Si necesitas pasar información de campos de una base de datos a variables, puedes hacerlo rápidamente usando el método GetRows del objeto Recordset. El método GetRows copia una o más filas de datos directamente en una variable variant guardando la información en una matriz de dos dimensiones (Campo,Fila). Es decir, al variar el primer índice recorremos los distintos campos de un registro (fila) y al variar el segundo recorremos los distintos registros (filas) recuperados.

Para probar el método GetRow añade un botón en un formulario y copia el código que hay a continuación en el evento click del botón. Asegúrate de que esté bien la localización de la base de datos BIBLIO.MDB en el método OpenDatabase y de tener activada la referencia a Microsoft DAO 3.5.

Private Sub cmdGetDataRow_Click()
    '
    ' show getrow method
    '
    Dim ws As Workspace
    Dim db As Database
    Dim rs As Recordset
    '
    Dim varDataRows As Variant
    Dim intRows As Integer
    Dim intColumns As Integer
    '
    Dim intLoopRow As Integer
    Dim intLoopCol As Integer
    Dim strMsg As String
    '
    Set ws = DBEngine.CreateWorkspace(App.EXEName, "admin", "")
    Set db = ws.OpenDatabase("c:\Archivos de programa\devstudio\vb\biblio.mdb")
    Set rs = db.OpenRecordset("SELECT * FROM Authors")
    '
    intRows = InputBox("¿Cuántas filas?", "Ejemplo de GetRows", 0)
    intColumns = rs.Fields.Count
    varDataRows = rs.GetRows(intRows)
    '
    For intLoopRow = 0 To intRows - 1
        strMsg = ""
        For intLoopCol = 0 To intColumns - 1
            strMsg = strMsg & varDataRows(intLoopCol, intLoopRow) & vbCrLf
        Next
        MsgBox strMsg
    Next
    '
    rs.Close
    db.Close
    ws.Close
    '
End Sub

From--Michael C. Amundsen [mike@amundsen.com, http://www.amundsen.com]