Resumen Saber si estamos conectados a internet y cómo

Mensaje enviado por "JuriSoft-Desarrollo" <desarrollo@jurisoft.es>

Hace tiempo preguntamos ¿Como sabes si el ordenador tiene conexion a internet?

Y la solución funcionó, salvo si estás conectado a traves de un router.

Esta es la solución para todo tipo de conexion.

Esta sacado de esta WEB donde hay soluciones para todo: http://www.mvps.org/vbnet/

'EN UN MODULO:

Option Explicit
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Copyright ©1996-2000 VBnet, Randy Birch, All Rights Reserved.
' Some pages may also contain other copyrights by the author.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' You are free to use this code within your own applications,
' but you are expressly forbidden from selling or otherwise
' distributing this source code without prior written consent.
' This includes both posting free demo projects made from this
' code as well as reproducing the code in text or html format.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Public Declare Function InternetGetConnectedState _
   Lib "wininet.dll" (ByRef lpdwFlags As Long, _
   ByVal dwReserved As Long) As Long

'Local system uses a modem to connect to the Internet.
Public Const INTERNET_CONNECTION_MODEM As Long = &H1

'Local system uses a LAN to connect to the Internet.
Public Const INTERNET_CONNECTION_LAN As Long = &H2

'Local system uses a proxy server to connect to the Internet.
Public Const INTERNET_CONNECTION_PROXY As Long = &H4

'No longer used.
Public Const INTERNET_CONNECTION_MODEM_BUSY As Long = &H8

Public Const INTERNET_RAS_INSTALLED As Long = &H10
Public Const INTERNET_CONNECTION_OFFLINE As Long = &H20
Public Const INTERNET_CONNECTION_CONFIGURED As Long = &H40


'InternetGetConnectedState wrapper functions
Public Function IsNetConnectViaLAN() As Boolean

   Dim dwflags As Long

  'pass an empty varialbe into which the API will
  'return the flags associated with the connection
   Call InternetGetConnectedState(dwflags, 0&)

  'return True if the flags indicate a LAN connection
   IsNetConnectViaLAN = dwflags And INTERNET_CONNECTION_LAN

End Function


Public Function IsNetConnectViaModem() As Boolean

   Dim dwflags As Long

  'pass an empty varialbe into which the API will
  'return the flags associated with the connection
   Call InternetGetConnectedState(dwflags, 0&)

  'return True if the flags indicate a modem connection
   IsNetConnectViaModem = dwflags And INTERNET_CONNECTION_MODEM

End Function


Public Function IsNetConnectViaProxy() As Boolean

   Dim dwflags As Long

  'pass an empty varialbe into which the API will
  'return the flags associated with the connection
   Call InternetGetConnectedState(dwflags, 0&)

  'return True if the flags indicate a proxy connection
   IsNetConnectViaProxy = dwflags And INTERNET_CONNECTION_PROXY

End Function


Public Function IsNetConnectOnline() As Boolean

  'no flags needed here - the API returns True
  'if there is a connection of any type
   IsNetConnectOnline = InternetGetConnectedState(0&, 0&)

End Function


Public Function IsNetRASInstalled() As Boolean

   Dim dwflags As Long

  'pass an empty varialbe into which the API will
  'return the flags associated with the connection
   Call InternetGetConnectedState(dwflags, 0&)

  'return True if the falgs include RAS installed
   IsNetRASInstalled = dwflags And INTERNET_RAS_INSTALLED

End Function


Public Function GetNetConnectString() As String

   Dim dwflags As Long
   Dim msg As String

  'build a string for display
   If InternetGetConnectedState(dwflags, 0&) Then

      If dwflags And INTERNET_CONNECTION_CONFIGURED Then
         msg = msg & "You have a network connection configured." & vbCrLf
      End If

      If dwflags And INTERNET_CONNECTION_LAN Then
         msg = msg & "The local system connects to the Internet via a LAN"
      End If

      If dwflags And INTERNET_CONNECTION_PROXY Then
            msg = msg & ", and uses a proxy server. "
      Else: msg = msg & "."
      End If

      If dwflags And INTERNET_CONNECTION_MODEM Then
         msg = msg & "The local system uses a modem to connect to the
Internet. "
      End If

      If dwflags And INTERNET_CONNECTION_OFFLINE Then
         msg = msg & "The connection is currently offline. "
      End If

      If dwflags And INTERNET_CONNECTION_MODEM_BUSY Then
         msg = msg & "The local system's modem is busy with a non-Internet
connection. "
      End If

      If dwflags And INTERNET_RAS_INSTALLED Then
         msg = msg & "Remote Access Services are installed on this system."
      End If

   Else

      msg = "Not connected to the internet now."

   End If

   GetNetConnectString = msg

End Function
'--end block--'



EN UN FORMULARIO CON 6 TEXT (TEXT1,TEXT2,TEXT3....ETC)

Private Sub Command1_Click()

   Text1 = IsNetConnectViaLAN()
   Text2 = IsNetConnectViaModem()
   Text3 = IsNetConnectViaProxy()
   Text4 = IsNetConnectOnline()
   Text5 = IsNetRASInstalled()
   Text6 = GetNetConnectString()
'SI CUALQUIERA DE LAS CINCO PRIMERAS FUNCIONES DEVULEVE TRUE, hay conexion a
internet..
End Sub

salu2:


Roberto Alonso
mailto:desarrollo@jurisoft.es



Resumen Resumen

Visual Basic Página de Visual Basic

Página principal Página principal

www.jrubi.com