Mensaje enviado por Jordi Ordiñana <qvestor@teleline.es>
A ver si te sirve el código que adjunto.
Un cordial saludo.
Jordi Ordiñana.
Barcelona - España.
mailto:qvestor@teleline.es
---- CODIGO PARA OBTENER DATOS DE CARPETAS Y FICHEROS ----
Option Explicit
' En Referencias: Microsoft Scripting Runtimes
' En el Form: un botón Command1 y un textbox multiline Text1
Private Sub Command1_Click()
Dim fs As Scripting.FileSystemObject
Dim nPath As Folder, nFolder As Folder, nf As Folders
Dim nFile As File, nff As Files
Dim strSize As String
' Cargamos objetos
Set fs = CreateObject("Scripting.FileSystemObject")
Set nPath = fs.GetFolder("C:\Mis documentos")
Set nf = nPath.SubFolders
Set nff = nPath.Files
' Cabecera
Text1.Text = " Tipo Nombre" & Space(93) & _
"- Tamaño - Creado " & _
"- Ultimo acceso " & _
"- Modificado" & Chr(13) & Chr(10) & _
String(193, "-") & Chr(13) & Chr(10)
' Datos de subcarpetas
For Each nFolder In nf
With nFolder
strSize = Format$(.Size, "#,##0 Kb")
Text1.Text = Text1.Text & "Folder: " & _
UCase(Left(.Name & Space(100), 100)) & " - " & _
Space(15 - Len(strSize)) & strSize & " - " & _
Format$(.DateCreated, "dd/mm/yyyy hh:nn:ss") & " - " & _
Format$(.DateLastAccessed, "dd/mm/yyyy hh:nn:ss") & _
" - " & _
Format$(.DateLastModified, "dd/mm/yyyy hh:nn:ss") & _
Chr(13) & Chr(10)
End With
Next
' Datos de ficheros
For Each nFile In nff
With nFile
strSize = Format$(.Size, "#,##0 Kb")
Text1.Text = Text1.Text & "File: " & _
Left(.Name & Space(100), 100) & " - " & _
Space(15 - Len(strSize)) & strSize & " - " & _
Format$(.DateCreated, "dd/mm/yyyy hh:nn:ss") & " - " & _
Format$(.DateLastAccessed, "dd/mm/yyyy hh:nn:ss") & _
" - " & _
Format$(.DateLastModified, "dd/mm/yyyy hh:nn:ss") & _
Chr(13) & Chr(10)
End With
Next
' Descargamos objetos
Set nFile = Nothing
Set nFolder = Nothing
Set nf = Nothing
Set nff = Nothing
Set nPath = Nothing
Set fs = Nothing
End Sub
-----Mensaje original-----
De: Mauricio Perez (personal) [mailto:mpgp@geo.net.co]
Enviado el: domingo, 05 de noviembre de 2000 15:33
Para: visualbasic-esp@egroups.com
Asunto: (VB-ESP) Off Topic: Impresion de contenido de subdirectorios
Hola todos
Alguno de ustedes conoce algun programa de utilidad (o comando o instruccion
de windows) que me permita imprimir todo el contenido de un subdirectorio
con sus carpetas y archivos (ojala con los detalles del archivo de tamano, y
fecha) en un cuadro de texto, de tal forma que luego se pueda cortar y
pegar el contenido de este cuadro de texto en otro programa como word o
power point..
De antemano agradezco su colaboracion
Mauricio Perez B