No creo que la pregunta sea Off Topic porque se puede resolver por VB.
El siguiente es el código ( Ojo, no lo he probado)
Te diseñas un programita que haga los calculos y te los presente en pantalla, algo como la calculadora del WIndows, Solo que este hace cualquie conversion.
Espero te sirva.
' Convierte un numero n a cualquier otro de basa 2 hasta 36
'
Public Function Long2Base(ByVal n As Long, ByVal nB As Integer) As String
Dim s As String
Dim nD As Integer
Dim Negative As Boolean
Negative = n < 0
n = Abs(n)
Do
nD = n Mod nB
If nD > 9 Then
nD = nD + 7
End If
s = Chr$(48 + nD) & s
n = n \ nB
Loop Until n = 0
If Negative Then
s = "-" & s
End If
Long2Base = s
End Function
------------------------------------------
' Convertir un Numero en Cualquier otro de base 2 hasta 36 a un Long
' Hay que tener cuidado con la funcion ya que no chequea si
' el String es un número valido segun la base
Public Function Base2Long(s As String, ByVal nB As Integer) As Long
Dim s2 As String
Dim i As Long
Dim j As Long
Dim X As Long
Dim n As Boolean
Dim s3 As String
If Len(s) < 1 Then
Base2Long = 0
Exit Function
End If
s2 = UCase(s)
If Left$(s2, 1) = "-" Then
n = True
s2 = Right$(s2, Len(s2) - 1)
Else
n = False
End If
j = 1
X = 0
For i = Len(s2) To 1 Step -1
s3 = Mid$(s2, i, 1)
Select Case s3
Case "0" To "9":
X = X + j * (Asc(s3) - 48)
Case "A" To "Z":
X = X + j * (Asc(s3) - 55)
End Select
j = j * nB
Next i
If n Then
X = -X
End If
Base2Long = X
End Function
73's de Asdrubal Velasquez
Puerto Ordaz - Venezuela
Internet E-Mail:
Packet Ax25: "
ICQ #7993678
-----Original Message-----
From: tronco <
To:
Date: martes 10 de marzo de 1998 9:09
Subject: (VB-ESP) Off-Topic
>Hola amigos.
>
>Perdón por la pregunta fuera del entorno.
>
>Conoce alguien alguna herramienta capaz de transformar de decimal a
>hexadecimal, binario, etc ...
>
>Gracias.
>
Resumen